// PoVRay 3.5 Scene File "RGB-Colors.pov"
// created by   Gerhard Höberth  
// Date:   March 2005
// Homepage: www.crearto.de
// Email: info@crearto.de
// This is a scene to see the rgb colors in a first overview to make
// it easeyer to choose a color. The stepsize from ball to ball is 50 (0.2)
//--------------------------------------------------------------------------
#version 3.6;

global_settings {
    assumed_gamma 2.2
    ambient_light color rgb <1.0,1.0,1.0>
    max_trace_level 20
}

camera {
  location  <0.0, 0.0, -200.0>
  look_at   <0.0, 0.0, 0.0>
  direction 13.0*z 
  right     x*image_width/image_height
}  


//---------------------------------------------------------------------

light_source{<4000, 4000, -4000> color rgb<1,1,1> parallel point_at <0.0,0.0,0.0>} 

sky_sphere { pigment { gradient <0,1,0>
 color_map {[ 0.0  color rgb <0,0,0>]  
            [ 0.1  color rgb <0,0,0>]
            [ 0.92  color rgb <1,1,1>]
            [ 1.0  color rgb <0,0,0>]}
            rotate <-2.3,0,-90>}}

#declare Colorball = sphere{<0,0,0>,0.5 scale <1,1,1>}

union{
 #declare NrR = 0;    // start x
 #declare EndNrR = 6; // end   x
 #while (NrR < EndNrR) 
    // inner loop
    #declare NrG = 0;    // start y 
    #declare EndNrG = 6; // end    y
    #while (NrG < EndNrG) 
       // innerst loop
       #declare NrB = 0;     // start z
       #declare EndNrB = 6; // end   z
       #while (NrB < EndNrB) 
     //-------------------
       object  {Colorball 
                    translate <(int(mod(NrB,2))*6+NrG*1), (int(NrB/2)*6+NrR*1), 0>
       texture {    pigment { color rgb <NrR*0.2, NrG*0.2, NrB*0.2>}
                    finish {ambient 0.30 diffuse 0.80 phong 0.8 }
              }} 
     //-------------------
       #declare NrB = NrB + 1;  // next Nr z
       #end // --------------- end of loop z
       // end innerst loop
    #declare NrG = NrG + 1;  // next Nr y
    #end // --------------- end of loop y
    // end inner loop
 #declare NrR = NrR + 1;  // next Nr x
 #end // --------------- end of loop x
 // end loop
rotate<0,0,-90> 
translate<-8.5,5.5,0>} // end of union